/////////////////////////////////////////////
// Game Over 1
// Copyright (C) David Olofson, 2003
/////////////////////////////////////////////

SWEEP = 10;

w_format target, MONO16, 32000;
w_blank target, 48000, 0;

//Pulses
w_env AMPLITUDE,
		.1,	.05,
		1.3,	.05,
		.1,	0;
w_env MOD1, .1;

w_env FREQUENCY,
		0,	43.9,
		1.5,	43.9 - SWEEP;
w_osc target, PULSE;

w_env FREQUENCY,
		0,	44.1,
		1.5,	44.1 - SWEEP;
w_osc target, PULSE;

w_env FREQUENCY,
		0,	88,
		1.5,	88 - SWEEP;
w_osc target, PULSE;

//LF
w_env AMPLITUDE, .2;
w_env FREQUENCY,
		0,	22,
		1.5,	22 - SWEEP;
w_env MOD1, .5;
w_osc target, SINE;

//noise
w_env AMPLITUDE, .05;
w_env MOD1, 20000;
w_env FREQUENCY,
		0,	1000,
		1.5,	50;
w_osc target, NOISE;

//Filters
w_env MOD1, 0;
w_env AMPLITUDE, 50;
w_env FREQUENCY,
		0,	700,
		.6,	5300,
		.9,	200;
w_filter target, LOWPASS_12;

w_env AMPLITUDE, 40;
w_env FREQUENCY,
		0,	300,
		.6,	700,
		.9,	30;
w_filter target, PEAK_12;

//Envelope
w_env AMPLITUDE,
		.1,	1,
		1,	.5,
		.4,	0;
w_gain, target;
